線性代數

tags: Numerical Methods

對於數值分析領域的研究者來說，線性代數是一個非常好的工具。它不僅可以協助我們將繁雜的數學式進行化簡（例如方程組轉換成矩陣的形式，並利用 Cramer's Rule 求解），同時也能夠利用線性代數的各種性質推廣數值分析上重要的內涵。

Symbolics套件與變數設定

在安裝完套件後，我們可以先對符號進行定義，也就是將其令為變數(variables)。

using Symbolics
@variables a b c d e f g h i j k l m n;

不過，為什麼要進行上面的步驟呢？我們來做個實驗，如果在 kernel 上面打上 p 會出現什麼呢？

UndefVarError: p not defined

Stacktrace:
 [1] top-level scope
   @ :0
 [2] eval
   @ .\boot.jl:373 [inlined]
 [3] include_string(mapexpr::typeof(REPL.softscope), mod::Module, code::String, filename::String)
   @ Base .\loading.jl:1196

很明顯的，因為我們還未定義 p 在這個程式裡面的意義，因此

$\mathtt{\text{Julia}}$ 不會知道這個 p 是一個變數。設定完成之後，我們可以隨意打上我們剛剛設定的那些符號，它就會顯示為數學符號（也就是

$LATEX$）的形式了。

a

它就會跑出

$$a$$

向量(vector)

給定兩個欄向量(column vector)

$M_1$ 與

$N_1$，

a = [m₁; m₂; m₃]
b = [n₁; n₂; n₃]
a |> display
b |> display

$$a=\left[\begin{array}{c}{m}_1\\ m_2\\ m_3\end{array}\right],b=\left[\begin{array}{c}{n}_1\\ n_2\\ n_3\end{array}\right]$$

內積(inner product)

若將兩向量進行內積，就會得到一個純量，即

a' * b |> display

$$a\cdot b=\left[\begin{array}{ccc}{m}_1& m_2& m_3\end{array}\right]\left[\begin{array}{c}{n}_1\\ n_2\\ n_3\end{array}\right]=m_1{n}_1+m_2{n}_2+m_3{n}_3$$

上述的結果也可以透過逐元的方式計算：

sum(m1 .* n1) |> display

正交(orthogonal)

如果說兩個向量的內積為

$0$，則我們說這兩個向量相互垂直(orthogonal)，或稱為正交的。

u = [3; 2; 1]
v = [-2; 3; 0]
u'v |> display

## 0

範數(norm)

而向量的範數是一個計算向量長度的方式，其計算方式為

$$\Vert m\Vert =\sqrt{M^{\prime }M}$$

m1_norm = sqrt(m1' * m1)

會得到

$$\sqrt{m{{}_1}^2+m{{}_2}^2+m{{}_3}^2}$$

若其長度為

$1$，則我們稱該向量為標準化向量。

m1_normalized = m1 ./ m1_norm
m1_normalized_norm = sqrt(m1_normalized' * m1_normalized)

m1_normalized |> display
m1_normalized_norm |> display

會得到標準化過後的向量為

$$\left[\begin{array}{c}\frac{m{}_1}{\sqrt{m{{}_1}^2+m{{}_2}^2+m{{}_3}^2}}\\ \frac{m{}_2}{\sqrt{m{{}_1}^2+m{{}_2}^2+m{{}_3}^2}}\\ \frac{m{}_3}{\sqrt{m{{}_1}^2+m{{}_2}^2+m{{}_3}^2}}\end{array}\right]$$

其長度為

$$\sqrt{\frac{m{{}_1}^2}{{\left(\sqrt{m{{}_1}^2+m{{}_2}^2+m{{}_3}^2}\right)}^2}+\frac{m{{}_2}^2}{{\left(\sqrt{m{{}_1}^2+m{{}_2}^2+m{{}_3}^2}\right)}^2}+\frac{m{{}_3}^2}{{\left(\sqrt{m{{}_1}^2+m{{}_2}^2+m{{}_3}^2}\right)}^2}}$$

經過化簡可得其長度為

$1$

simplify.(expand.(m1_normalized_norm))

$$\sqrt{\frac{m{{}_1}^2+m{{}_2}^2+m{{}_3}^2}{{\left(\sqrt{m{{}_1}^2+m{{}_2}^2+m{{}_3}^2}\right)}^2}}=1$$

而在計量經濟學中，我們最常使用的性質是標準正交(orthonormal)：若兩個向量相互垂直且均經過標準化，則稱這兩個向量具有標準正交的性質。

外積(outer product)

若將兩向量進行外積，就會得到一個張量(tensor)，即

a * b' |> display

$$a\times b^{\prime }=\left[\begin{array}{c}{m}_1\\ m_2\\ m_3\end{array}\right]\left[\begin{array}{ccc}{n}_1& n_2& n_3\end{array}\right]=\left[\begin{array}{ccc}{m}_1{n}_1& m_1{n}_2& m_1{n}_3\\ m_2{n}_1& m_2{n}_2& m_2{n}_3\\ m_3{n}_1& m_3{n}_2& m_3{n}_3\end{array}\right]$$

矩陣(matrix)

根據維基百科的定義，數學上，一個

$m\times n$的矩陣是一個由

$m$列(row)

$n$行(column)元素排列成的矩形陣列，如果用英文表達，就是一個

$m$ by

$n$ 的矩陣。矩陣裡的元素可以是數字、符號或數學式。^[1]我們來看看下面的例子：

## 2 x 2 的矩陣
A = [a b; c d]

## 2 x 3 的矩陣
B = [a b c
     d e f]

## 3 x 2 的矩陣
C = [a b; c d; e f]

A |> display
B |> display
C |> display

它便會顯示

$$\begin{gathered} \left[\begin{array}{cc}a& b\\ c& d\end{array}\right] \\ \left[\begin{array}{ccc}a& b& c\\ d& e& f\end{array}\right] \\ \left[\begin{array}{cc}a& b\\ c& d\\ e& f\end{array}\right] \end{gathered}$$

矩陣的符號表示

我們會以大寫（或粗體）的字母表示矩陣，例如

$\mathbf{A}$；利用小寫的字母代表矩陣內的元素，例如

$a$。注意到，在矩陣中為了清楚定義是哪一個元素，我們會利用以下的方式進行註記。

$${\mathbf{A}}_{i,j}$$

其中下標(subscript)

$i$ 代表行，

$j$ 代表列。如果我們要找到上面設定的矩陣

$\mathbf{B}$ 中第二列第三個元素，也就是

$f$，要怎麼輸入呢？

@show B[2, 3]

顯示

$$f$$

矩陣的四則運算

如果我們要將兩個矩陣進行相加，我們可寫成：

[a b
c d] + [e f
        g h]

其計算結果很直觀地可以猜想到是

$$\left[\begin{array}{cc}a+e& b+f\\ c+g& d+h\end{array}\right]$$

而有趣地是，在

$\mathtt{\text{Julia}}$ 中，我們可以將兩個不同維度(dimension)的矩陣進行相加總，不過必須利用**逐元(element-wise)**的方式進行運算。^[2]例如

[a b
c d] .+ [e
        g]

結果會是

$$\left[\begin{array}{cc}a+e& b+e\\ c+g& d+g\end{array}\right]$$

接著我們來看一下乘積。首先定義兩個矩陣，

${\mathbf{A}}_1$ 與

${\mathbf{A}}_2$。

A1 = [a b; c d]
A2 = [e f; g h]

如果我們要計算兩個矩陣相乘，即

${\mathbf{A}}_1\cdot {\mathbf{A}}_2$；或是在矩陣前方乘上一個純量(scalar)，也就是

$c\cdot {\mathbf{A}}_1$，我們可以這麼做：

A12 = A1 * A2 # 兩個矩陣相乘
A3 = 3 * A1 # 純量乘上矩陣

結果就是

$$\begin{gathered} {\mathbf{A}}_1\cdot {\mathbf{A}}_2=\left[\begin{array}{cc}ae+bg& af+bh\\ ce+dg& cf+dh\end{array}\right] \\ 3\cdot {\mathbf{A}}_1=\left[\begin{array}{cc}3a& 3b\\ 3c& 3d\end{array}\right] \end{gathered}$$

同樣地，我們也可以運用

$\mathtt{\text{Julia}}$ 中逐元的性質對矩陣進行乘積。例如

A3 = A1 .* A2 # 進行逐元乘積

則

${\mathbf{A}}_3$ 會等於

$$\left[\begin{array}{cc}ae& bf\\ cg& dh\end{array}\right]$$

注意到，如果我們對

${\mathbf{A}}_1$ 與

${\mathbf{A}}_2$ 的乘積進行交換，其結果在數學上與在

$\mathtt{\text{Julia}}$ 上均是不成立的，這部分就留給讀者自行證明。

A21 = A2 * A1

會得到

$${\mathbf{A}}_2\cdot {\mathbf{A}}_1=\left[\begin{array}{cc}ae+cf& be+df\\ ag+ch& bg+dh\end{array}\right]$$

值得一提的是，給定兩個矩陣，其中

${\mathbf{X}}_1$ 為一個

$p\times q$ 的矩陣，

${\mathbf{X}}_2$ 則是一個

$s\times t$ 的矩陣。而只有在

$q=s$時，兩個矩陣才能進行乘積，並得到一個新的矩陣

${\mathbf{X}}_3$，且為一

$p\times t$ 的矩陣。

行列式

行列式(determinant)，記作

$det(\mathbf{A})$ 或

$|\mathbf{A}|$，是一個在方陣上計算得到的純量。^[3]如果要進行計算的話，首先要引入套件 LinearAlgebra，接著利用指令 det() 計算行列式。

using LinearAlgebra

A |> display
@show det(A)

結果會是

$$\begin{gathered} \left[\begin{array}{cc}a& b\\ c& d\end{array}\right] \\ \mathtt{\text{det}}(\mathbf{A})=ad-bc \end{gathered}$$

如果考慮以下矩陣

$\mathbf{D}$

$$\left[\begin{array}{ccc}a& b& c\\ d& e& f\\ g& h& i\end{array}\right]$$

則其行列式為

$$\mathtt{\text{det}}(\mathbf{D})=c(dh-eg)+a(ei-fh)-b(di-fg)$$

其實到了高維的矩陣，可以看到行列式的計算變得複雜，因此我們可以利用 expand.() 的指令，將計算過程展開，了解其背後的運作、計算過程與原理。

@show expand.(det(D))

## b*f*g + a*e*i + c*d*h - b*d*i - c*e*g - a*f*h

有關乘法，我們要注意一件事：

$\mathbf{AB}\mathbf{=}\mathbf{AC}$ 並不隱含

$\mathbf{B}\mathbf{=}\mathbf{C}$。

a1 = [1 2; 2 4]
b1 = [2 1; 1 3]
c1 = [4 3; 0 2]

@show a1 * b1
@show a1 * c1

## a1 * b1 = [4 7; 8 14]
## a1 * c1 = [4 7; 8 14]

另外給定

$\mathbf{A}$、

$\mathbf{B}$ 與

$\mathbf{C}$ 三個矩陣，如果

$\mathbf{A}(\mathbf{BC})=(\mathbf{AB})\mathbf{C}$，那麼我們就稱其符合結合律。

A*(B*C) |> display
(A*B)*C |> display

輸出的結果如下：

$$\begin{gathered} \left[\begin{array}{cc}a(a^2+bc+ce)+b(ad+ce+ef)& a(ab+bd+cf)+b(bd+de+f^2)\\ c(a^2+bc+ce)+d(ad+ce+ef)& c(ab+bd+cf)+d(bd+de+f^2)\end{array}\right] \\ \left[\begin{array}{cc}a(a^2+bd)+c(ab+be)+e(ac+bf)& b(a^2+bd)+d(ab+be)+f(ac+bf)\\ a(ac+d^2)+c(bc+de)+e(c^2+df)& b(ac+d^2)+d(bc+de)+f(c^2+df)\end{array}\right] \end{gathered}$$
但基本上由上面的結果我們很難看出兩者到底是不是相同的，因此我們可利用 simplify.() 的指令，配合上面使用過的 expand.()，將其進行展開後化簡成最易讀的形式。

simplify.(expand.(A*(B*C))) |> display
simplify.(expand.((A*B)*C)) |> display

$$\begin{gathered} \left[\begin{array}{cc}{a}^3+ab(c+d)+bef+ce(a+b)& b(a^2+f^2)+b^{2}d+abd+bde+acf\\ d^{2}a+a^{2}c+c^2(b+e)+cde+def& c^{2}f+d^2(b+e)+f^{2}d+abc+bcd\end{array}\right] \\ \left[\begin{array}{cc}{a}^3+ab(c+d)+bef+ce(a+b)& b(a^2+f^2)+b^{2}d+abd+bde+acf\\ d^{2}a+a^{2}c+c^2(b+e)+cde+def& c^{2}f+d^2(b+e)+f^{2}d+abc+bcd\end{array}\right] \end{gathered}$$

單位矩陣(identity matrix)

單位矩陣就是一個

$n\times n$ 的方陣，其主對角線(main diagonal)上的元素均為

$1$，其餘元素為

$0$。以一個

$4\times 4$ 的單位矩陣

${\mathbf{I}}_4$ 為例，其可寫作

$$\left[\begin{array}{cc}1& 0\\ 0& 1\end{array}\right]$$

注意到，如果我們將單位矩陣與其他矩陣相乘，其是具有交換律的，且結果會等於被乘矩陣，即

$\mathbf{AI}\mathbf{=}\mathbf{A}\mathbf{=}\mathbf{IA}$。

Imat = [1 0; 0 1]

A * Imat |> display
Imat * A |> display

$$\begin{gathered} \left[\begin{array}{cc}a& b\\ c& d\end{array}\right] \\ \left[\begin{array}{cc}a& b\\ c& d\end{array}\right] \end{gathered}$$

對角矩陣(diagonal matrix)

若一個矩陣主對角線之外的元素皆為

$0$，那麼我們就稱其為對角矩陣。例如

d = [a 0 0; 0 b 0; 0 0 c]

$$\left[\begin{array}{ccc}a& 0& 0\\ 0& b& 0\\ 0& 0& c\end{array}\right]$$

如果兩個對角矩陣相乘，其結果也會是一個對角矩陣。

D1 = [1 0 0; 0 2 0; 0 0 3]
D2 = [4 0 0; 0 5 0; 0 0 6]
D1D2 = D1 * D2

D1 |> display
D2 |> display
D1D2 |> display

結果會是

$$\left[\begin{array}{ccc}4& 0& 0\\ 0& 10& 0\\ 0& 0& 18\end{array}\right]$$

三角矩陣(triangular matrix)

其分為上三角與下三角矩陣，前者的對角線左下方元素為

$0$，後者則是對角線右上方元素為

$0$。

UT = [a b c; 0 d e; 0 0 f]
LT = [a 0 0; b c 0; d e f]

UT |> display
LT |> display

得到上三角矩陣

$$\left[\begin{array}{ccc}a& b& c\\ 0& d& e\\ 0& 0& f\end{array}\right]$$
與下三角矩陣

$$\left[\begin{array}{ccc}a& 0& 0\\ b& c& 0\\ d& e& f\end{array}\right]$$

同樣地，我們將三角矩陣相乘的結果仍會是三角矩陣。

UT * UT |> display

$$\left[\begin{array}{ccc}{a}^2& ab+bd& ac+be+cf\\ 0& d^2& de+ef\\ 0& 0& f^2\end{array}\right]$$

轉置矩陣(transpose of matrix)

簡單來說，轉置矩陣就是將行、列進行交換。下面定義

$\mathbf{M}$ 與

$\mathbf{N}$ 兩個矩陣，並對

$\mathbf{M}$ 取轉置矩陣，在數學上我們記做

${\mathbf{M}}^{\mathrm{\top }}$ 或

${\mathbf{M}}^{\prime }$。

@variables m₁₁ m₁₂ m₁₃ m₂₁ m₂₂ m₂₃ m₁ m₂ m₃
 
M = [ m₁₁ m₁₂ m₁₃
      m₂₁ m₂₂ m₂₃ ]

@variables n₁₁ n₁₂ n₁₃ n₂₁ n₂₂ n₂₃ n₃₁ n₃₂ n₁ n₂ n₃

N = [ n₁₁ n₁₂
      n₂₁ n₂₂
      n₃₁ n₃₂ ]

M |> display
M' |> display

$$\begin{gathered} \left[\begin{array}{ccc}m{}_{11}& m{}_{12}& m{}_{13}\\ m{}_{21}& m{}_{22}& m{}_{23}\end{array}\right] \\ \left[\begin{array}{cc}m{}_{11}& m{}_{21}\\ m{}_{12}& m{}_{22}\\ m{}_{13}& m{}_{23}\end{array}\right] \end{gathered}$$

而轉置矩陣有下列的性質。如果將矩陣進行轉置，再對其進行一次轉置，我們會得到原本的矩陣：

$$({\mathbf{M}}^{\prime }{)}^{\prime }=\mathbf{M}$$

如果我們將兩個矩陣相加再轉置，可以寫成兩個矩陣先進行轉置後再進行相加

$$(\mathbf{M}+\mathbf{N}{)}^{\prime }={\mathbf{M}}^{\prime }+{\mathbf{N}}^{\prime }$$

而兩個矩陣先進行相乘再轉至，其結果為

$$(\mathbf{MN}{)}^{\prime }={\mathbf{N}}^{\prime }{\mathbf{M}}^{\prime }$$

道理很簡單，我們令

$\mathbf{M}$ 為一個

$m\times n$ 的矩陣，

$\mathbf{N}$ 為一個

$n\times m$ 的矩陣，兩者相乘的結果會是

$m\times m$ 的結果。而如果將

$\mathbf{M}$ 轉置，會得到一個

$n\times m$ 的矩陣，將

$\mathbf{N}$ 進行轉置則會得到一個

$m\times n$ 的矩陣，故若為

${\mathbf{M}}^{\prime }{\mathbf{N}}^{\prime }$，其結果會是一個

$n\times n$ 的矩陣；如果是

${\mathbf{N}}^{\prime }{\mathbf{M}}^{\prime }$，則會是

$m\times m$ 的矩陣。

(M*N)' |> display
N'M' |> display
M'N' |> display

$$\begin{gathered} \left[\begin{array}{cc}m{}_{11}n{}_{11}+m{}_{12}n{}_{21}+m{}_{13}n{}_{31}& m{}_{21}n{}_{11}+m{}_{22}n{}_{21}+m{}_{23}n{}_{31}\\ m{}_{11}n{}_{12}+m{}_{12}n{}_{22}+m{}_{13}n{}_{32}& m{}_{21}n{}_{12}+m{}_{22}n{}_{22}+m{}_{23}n{}_{32}\end{array}\right] \\ \left[\begin{array}{cc}m{}_{11}n{}_{11}+m{}_{12}n{}_{21}+m{}_{13}n{}_{31}& m{}_{21}n{}_{11}+m{}_{22}n{}_{21}+m{}_{23}n{}_{31}\\ m{}_{11}n{}_{12}+m{}_{12}n{}_{22}+m{}_{13}n{}_{32}& m{}_{21}n{}_{12}+m{}_{22}n{}_{22}+m{}_{23}n{}_{32}\end{array}\right] \\ \left[\begin{array}{ccc}m{}_{11}n{}_{11}+m{}_{21}n{}_{12}& m{}_{11}n{}_{21}+m{}_{21}n{}_{22}& m{}_{11}n{}_{31}+m{}_{21}n{}_{32}\\ m{}_{12}n{}_{11}+m{}_{22}n{}_{12}& m{}_{12}n{}_{21}+m{}_{22}n{}_{22}& m{}_{12}n{}_{31}+m{}_{22}n{}_{32}\\ m{}_{13}n{}_{11}+m{}_{23}n{}_{12}& m{}_{13}n{}_{21}+m{}_{23}n{}_{22}& m{}_{13}n{}_{31}+m{}_{23}n{}_{32}\end{array}\right] \end{gathered}$$

對稱矩陣與反對稱矩陣

若一個矩陣之轉置矩陣仍是其自己本身，那麼其便符合對稱矩陣的性質，即

$A^{\prime }=A$。

S = [a b c; b d e; c e f]
S |> display
S' |> display

$$\begin{gathered} \left[\begin{array}{ccc}a& b& c\\ b& d& e\\ c& e& f\end{array}\right] \\ \left[\begin{array}{ccc}a& b& c\\ b& d& e\\ c& e& f\end{array}\right] \end{gathered}$$

而反對稱矩陣則是其轉置矩陣與自身的加法反元素相等，即

$${\mathbf{A}}^{\prime }=-\mathbf{A}$$

SS = [0 b c; -b 0 e; -c -e 0]
SS |> display
SS' |> display

$$\begin{gathered} \left[\begin{array}{ccc}0& b& c\\ -b& 0& e\\ -c& -e& 0\end{array}\right] \\ \left[\begin{array}{ccc}0& -b& -c\\ b& 0& -e\\ c& e& 0\end{array}\right] \end{gathered}$$

注意到，如果一個矩陣的轉置矩陣乘上該矩陣，結果會是一個對稱矩陣，即

$${\mathbf{A}}^{\prime }\mathbf{A}$$

A' * A |> display
B' * B |> display

$$\begin{gathered} \left[\begin{array}{cc}{a}^2+c^2& ab+cd\\ ab+cd& b^2+d^2\end{array}\right] \\ \left[\begin{array}{ccc}{a}^2+d^2& ab+de& ac+df\\ ab+de& b^2+e^2& bc+ef\\ ac+df& bc+ef& c^2+f^2\end{array}\right] \end{gathered}$$

反矩陣(inverse matrix)

給定一個

$n$ 階方陣

$\mathbf{A}$，若存在一

$n$ 階方陣

$\mathbf{B}$，使得

$\mathbf{AB}=\mathbf{BA}={\mathbf{I}}_n$，其中

${\mathbf{I}}_n$ 為

$n$ 階單位矩陣，則稱

$\mathbf{A}$ 是可逆的，且

$\mathbf{B}$ 是

$\mathbf{A}$ 的逆矩陣，記作

${\mathbf{A}}^{-1}$。但並非所有矩陣都可以取反矩陣，如果其行列式等於

$0$時，便不能取反矩陣。原因是因為如果矩陣

$\mathbf{A}$ 可逆，則

${\mathbf{A}}^{-1}=\frac{\mathrm{adj}(A)}{det(A)}$，其中

$\mathrm{adj}(A)$ 為矩陣

$\mathbf{A}$ 的伴隨矩陣(adjugate matrix)，故若行列式的值為

$0$，此等式就會無意義。根據上述性質，可得出以下小結論：若矩陣

$\mathbf{A}$ 可逆，則

$$\mathbf{A}{\mathbf{A}}^{-1}=\mathbf{I}={\mathbf{A}}^{-1}\mathbf{A}$$

A * inv(A)

得到

$$\left[\begin{array}{cc}1& 0\\ \frac{c(true+\frac{b\frac{c}{a}}{d+\frac{-bc}{a}})}{a}+\frac{-d\frac{c}{a}}{d+\frac{-bc}{a}}& \frac{d}{d+\frac{-bc}{a}}+\frac{-c\frac{b}{d+\frac{-bc}{a}}}{a}\end{array}\right]$$

經過化簡可以得到

simplify.(expand.(A * inv(A))) |> display
simplify.(expand.(inv(A) * A)) |> display

兩者結果均是

$$\mathbf{I}=\left[\begin{array}{cc}1& 0\\ 0& 1\end{array}\right]$$

而反矩陣有以下性質：

$$\begin{array}{r}(\mathbf{AB}{)}^{-1}={\mathbf{B}}^{-1}{\mathbf{A}}^{-1}\\ ({\mathbf{A}}^{\mathrm{\top }}{)}^{-1}=({\mathbf{A}}^{-1}{)}^{\mathrm{\top }}\end{array}$$

simplify.(expand.(inv(A'))) |> display
simplify.(expand.(inv(A)')) |> display

輸出結果均為

$$\left[\begin{array}{cc}\frac{d}{ad-bc}& \frac{-c}{ad-bc}\\ \frac{-b}{ad-bc}& \frac{a}{ad-bc}\end{array}\right]$$

那我們要怎麼手刻反矩陣呢？根據上面的定義，

$$\mathbf{A}{\mathbf{A}}^{-1}=\mathbf{I}$$

其實可以把反矩陣令為一個未知矩陣

$\mathbf{X}$，因此可以寫成

$$\mathbf{A}\mathbf{X}=\mathbf{I}$$

而利用反斜線(backslash)的運算符，我們可以計算出反矩陣，即

X = A\I

結果會是

$$\left[\begin{array}{cc}\frac{1+\frac{b\frac{c}{a}}{d+\frac{-bc}{a}}}{a}& \frac{-\frac{b}{d+\frac{-bc}{a}}}{a}\\ \frac{-\frac{c}{a}}{d+\frac{-bc}{a}}& \frac{1}{d+\frac{-bc}{a}}\end{array}\right]$$

經過化簡與檢查，確定該算法可得出反矩陣：

simplify.(expand.(inv(A))) |> display
simplify.(expand.(A \ I_mat)) |> display

$$\left[\begin{array}{cc}\frac{d}{ad-bc}& \frac{-b}{ad-bc}\\ \frac{-c}{ad-bc}& \frac{a}{ad-bc}\end{array}\right]$$

---

1. 參考自維基百科──矩陣 ↩︎

2. 注意到在數學上這件事是不成立的。 ↩︎

3. 參考自維基百科──行列式 ↩︎