---
# System prepended metadata

title: Untitled

---


## Twolc (morfofonologi)


```
!! =================================== !
!! The "Kildin Sami" morphophonological/twolc rules file !
!! =================================== !

Alphabet
  а А ӓ Ӓ а̄ А̄ б Б в В г Г д Д !!= * @CODE@  
  е Е ё Ё е̄ Е̄ ё̄ Ё̄ ж Ж з З һ Һ !!= * @CODE@ 
  и И ӣ Ӣ й Й ҋ Ҋ ј Ј к К л Л !!= * @CODE@ 
  ӆ Ӆ м М ӎ Ӎ н Н ӊ Ӊ ӈ Ӈ о О !!= * @CODE@ 
  о̄ О̄ п П р Р ҏ Ҏ с С т Т у У !!= * @CODE@ 
  ӯ Ӯ ф Ф х Х ц Ц ч Ч ш Ш щ Щ !!= * @CODE@ 
  ъ Ъ ы Ы ь Ь ъ Ъ ҍ Ҍ э Э ӭ Ӭ !!= * @CODE@ 
  э̄ Э̄ ю Ю ю̄ Ю̄ я Я я̄ Я̄         !!= * @CODE@ 

 %>:0 %^VCH:0 %^WG:0 
 ;

Sets

 Cns  = б Б в В г Г д Д ж Ж з З һ Һ й Й ҋ Ҋ ј Ј к К л Л ӆ Ӆ м М ӎ Ӎ н Н ӊ Ӊ ӈ Ӈ п П р Р ҏ Ҏ с С т Т ф Ф х Х ц Ц ч Ч ш Ш щ Щ ; !!= * @CODE@ 
 Palvow  = е Е е̄ Е̄ ё Ё ё̄ Ё̄ и И ӣ Ӣ ю Ю ю̄ Ю̄ я Я я̄ Я̄ ; !!= * @CODE@ 
 Semipalvow = ӓ Ӓ ӭ Ӭ ; !!= * @CODE@
 Nonpalvow = а А а̄ А̄ о О о̄ О̄ у У ӯ Ӯ ы Ы э Э э̄ Э̄ ; !!= * @CODE@
 Vow  = Palvow Semipalvow Nonpalvow ; !!= * @CODE@ 
 Longvow = а̄ А̄ е̄ Е̄ ё̄ Ё̄ ӣ Ӣ о̄ О̄ ӯ Ӯ ю̄ Ю̄ э̄ Э̄ я̄ Я̄ ; !!= * @CODE@
 Shortvow = а А е Е ё Ё и Ио О у У ы Ы ю Ю я Я э Э ӓ Ӓ ӭ Ӭ ; !!= * @CODE@

 
Definitions

Weakgrade = %^WG:0 ;

Rules

!! ## Consonant rules

!! ### Gradation rules

"xx > x"
Cx:0 <=> Vow: Cy _ Weakgrade ;
    where Cx in (в п т р н)
          Cy in (в б д р н)
          matched;

!!€ сувв^WG
!!€ сув00

!!€ кэ̄бп^WG
!!€ кэ̄б00

!!€ те̄дт^WG
!!€ те̄д00

!!€ ме̄рр^WG
!!€ ме̄р00

!!€ ме̄рр^WGэнҍ
!!€ ме̄р00энҍ

!!€ вӯнн^WGэнҍ
!!€ вӯн00энҍ


"xx˙ > x˙"
Cx:0 <=> Vow: Cx _ ҍ Weakgrade ;
    where Cx in (н) ;
    
!!€ нюннҍ^WG
!!€ нюн0ҍ0

!!€ нюннҍ^WG>ӭнҍ
!!€ нюн000>ӭнҍ

"xx’ > x’"	
Cx:0 <=> Vow: Cy _ (ь:) Weakgrade ;
    where Cx in (л к) 
          Cy in (л г)
          matched;

!!€ кӯлль^WG
!!€ кӯл0ь0 

!!€ кӯлль^WG>енҍ
!!€ кӯл000>енҍ

!!€ ыгкь^WG
!!€ ыг0ь0

!!€ ыгкь^WGесьт
!!€ ыг000есьт


"xxz > xz"
Cx:0 <=> Cx _ Cy %^WG: ;
    where Cx in (б н)
          Cy in (л т)
          matched ;
          
!!€ выббл^WG
!!€ выб0л^WG

!!€ рыннт^WG 
!!€ рын0т0

"xx˙z > x˙z"
Cx:0 <=> Cx _ ҍ Cy %^WG: ;
    where Cx in (н)
          Cy in (т)
          matched ;
          
!!€ сӯннҍт^WG
!!€ сӯн0ҍт0

"xx’z > x’z"	
Cx:0 <=> Cx _ ь Cy %^WG: ;
    where Cx in (р)
          Cy in (к)
          matched ;


!!€ е̄ррьк^WG
!!€ е̄р0ьк0


"йхх > йх"
Cx:0 <=> й _ Cx %^WG: ;
    where Cx in (х) ;
    
!!€ ла̄йхх^WG
!!€ ла̄й0х0


"йххz > йхz"
Cx:0 <=> й _ Cx Cns %^WG: ;
    where Cx in (х) ;

!!€ а̄йххт^WG
!!€ а̄йх0т0


!! 3)	Kvalitativa konsonantväxlingar: tonande ⟷ tonlös

"xx > X 1"
Cx:0 <=> Vow: _ Cx: %^WG: ;
    where Cx in (с ш ) ;
    
"xx > X 2"
Cx:Cy <=> Vow: Cx: _ %^WG: ;
    where Cx in (с ш ) 
          Cy in (з ж ) 
          matched ;

!!€ коа̄сс^WG
!!€ коа̄0з0

!!€ коа̄сс^WGэнҍ
!!€ коа̄0з0энҍ




!! 4)	Andra kvalitativa växlingar

"xz’ > z’"
Cx:0 <=> _ Cy ь %^WG: ;
    where Cx in (д)
          Cy in (ж)
          matched ;
          
!!€ аджь^WG
!!€ а0жь0

!!€ аджь^WGесьт
!!€ а0ж00есьт

! This is not right:
!"xz˙ > z˙"	
!Cx:0 <=> _ Cy ҍ %^WG: ;
!    where Cx in ()
!          Cy in ()
!          matched ;
!дтҍ > дҍ	рыдтҍ > рыдҍ, рыдӭтҍ




"ххz > zz 1"
Cx:0 <=> Vow _ Cx: Cz %^WG: ;
    where Cx in (х)
          Cz in (к)
          matched ;
          
"ххz > zz 2"
Cx:Cy <=> Cx: _ Cz %^WG: ;
    where Cx in (х)
          Cy in (г)
          Cz in (к)
          matched ;
    
!!€ лыххк^WG 
!!€ лы0гк0

!!€ лыххк^WG>этҍ
!!€ лы0гк0>этҍ



!! ## Palatalisation

!! 2)	Kvalitativa konsonantväxlingar: hårda stammar ⟷ mjuka stammar

"Half-palatalisation after дтн"
е:ӭ <=> [д|т|н] %> _ ;
!д, т, н skal ha ӭ og ikkje е


"Depalatalisation in illative"
ь:0 <=> _ (Cns) %> а ;

!!€ ва̄ррь>а
!!€ ва̄рр0>а

!!€ алльк>а
!!€ алл0к>а

"Desemipalatalisation in illative"
ҍ:0 <=> _ (Cns) %> а ;

!!€ ка̄ннҍц>а
!!€ ка̄нн0ц>а


"Palatalisation in illative and verbs"
0:ь <=> Cx Cx _ Cns %> э ;
    where Cx in (ш х) ;

!!€ кӯшш0к>э 
!!€ кӯшшьк>э

!!€ шкоа̄хх0п>э  
!!€ шкоа̄ххьп>э



!! ## Palatalisation marks
"Deleting ь in front of suffix vowel"
ь:0 <=> _ %> :Palvow ;

"Deleting ҍ in front of suffix vowel"
ҍ:0 <=> _ %> :Semipalvow ;



!! ## Vowel rules


!! ### Dipthong simplification

"уа, уэ to ӯ 1"
у:ӯ <=> _ [а:|э:] Cns:+ %> %^VCH: э ;


"уа, уэ to ӯ 2"
Vx:0 <=> у: _  Cns:+ %>  %^VCH: э ;
    where Vx in (а э) ;
    
!!€ туарр>^VCHэ
!!€ тӯ0рр>0э

!!€ вуэрр>^VCHэ
!!€ вӯ0рр>0э


"уэ to уа in front of suffix -а"
э:а <=> [у|ю] _ Cns:+ %> %^VCH: а ;



```