Week3- Token (ERC20) & NFT (ERC721)

Outline

• Ethereum Improvement Proposals (EIP)
• ERC20
• ERC721

Ethereum Improvement Proposals (EIP)

• 提案種類
  

• 提案流程
  

https://github.com/ethereum/EIPs/blob/master/EIPS/eip-1.md

Openzeppelin

https://docs.openzeppelin.com/contracts/5.x/

ERC20

• 以太坊上的「同質化代幣」標準。

• https://github.com/OpenZeppelin/openzeppelin-contracts/blob/master/contracts/token/ERC20/ERC20.sol

• 狀態變數：

  • _balances： 持幣紀錄。(address => uint256)
  • _allowances： 授權關係。 (address => (address => uint256))
  • _totalSupply：代幣供給量。
  • _name： 代幣名稱。
  • _symbol: 代幣簡稱。

• Function：

  • Get:
    • name()：取得代幣名稱。
    • symbol()：取得代幣簡稱。
    • decimals()：取得精度。
    • totalSupply()：取得總發行量。
    • balanceOf(address account)：取得「某地址」的「持幣量」。
  • Write:
    • transfer(address to, uint256 value)：轉移代幣。
    • approve(address spender, uint256 value)：授權「某地址」操作「某數量」代幣。
    • transferFrom(address from, address to, uint256 value)：轉移代幣，通常「被授權者」會呼叫這個。
  • internal:
    • _mint(address account, uint256 value)：鑄造代幣。
    • _burn(address account, uint256 value)：燒掉代幣。

• Demo

// SPDX-License-Identifier: GPL-3.0
pragma solidity >=0.8.20;

import "@openzeppelin/contracts/token/ERC20/ERC20.sol";

contract ERC20Example is ERC20 {

    // 定義最大供給量
    uint256 public maxSupply;

    //建構子初始化ERC20必要參數(name與symbol)，並多加設定題目要求的maxSupply
    constructor(
        string memory _name, 
        string memory _symbol,
        uint256 _maxSupply
        ) ERC20(_name, _symbol){
        //執行時填入10000000000(100億) * 1000000000000000000(單位)
        maxSupply = _maxSupply;
    }

    // 實作mint function，主要用來demo確認用
    function mint (uint256 amount) external {
        //判斷這筆交易若完成，是否會超出最大供給量，如果會就回傳錯誤字串"over max supply."
        require(amount + totalSupply() <= maxSupply, "over max supply.");
        _mint(msg.sender, amount);
    }
}

ERC721

• 以太坊上的「非同質化代幣」標準。

• https://github.com/OpenZeppelin/openzeppelin-contracts/blob/master/contracts/token/ERC721/ERC721.sol

• 狀態變數：

  • _name: 代幣名稱。
  • _symbol：代幣簡稱。
  • _owners：代幣id與擁有者關係。(uint256 => address)
  • _balances: 持幣紀錄。(address => uint256)
  • _tokenApprovals: 代幣單個id授權紀關係。(uint256 => address)
  • _operatorApprovals: 全部持有id授權關係。(address ==> ( address = >bool))

• Funtion:

  • Get:
    • name() : 取得代幣名稱。
    • symbol() ：取得代幣簡稱。
    • balanceOf(address owner)：取得「某地址」持有NFT「數量」。
    • ownerOf(uint256 tokenId)：取得「某代幣Id」的擁有者地址。
    • tokenURI(uint256 tokenId)：取得NFT的圖片資訊。
    • getApproved(uint256 tokenId): 取得「某代幣Id」授權給哪個地址。
    • isApprovedForAll(address owner, address operator)：取得「某地址(owner)」是否授權「所有的代幣Id」給「某地址{operator}」。
  • Write:
    • approve(address to, uint256 tokenId)：授權持有的「某代幣Id」NFT給「某地址」。
    • setApprovalForAll(address operator, bool approved)：設定「所有持有的代幣Id」都授權給「某地址」。
    • transferFrom(address from, address to, uint256 tokenId): 轉移NFT。
  • Internal:
    • _mint(address to, uint256 tokenId)： 鑄造NFT。
    • _burn(uint256 tokenId)：燒掉NFT。

• Demo

// SPDX-License-Identifier: GPL-3.0
pragma solidity ^0.8.20;

import "@openzeppelin/contracts/token/ERC721/ERC721.sol";

contract ERC721Example is ERC721 {

    // 定義最大供給量
    uint256 public maxSupply;
    uint256 public counter = 0;

    modifier avaialbeMint(uint256 amount) {
        //判斷這筆交易若完成，是否會超出最大供給量，如果會就回傳錯誤字串"over max supply."
        require(amount + counter <= maxSupply, "over max supply.");
        _;
    }

    //建構子初始化ERC721必要參數(name與symbol)，並多加設定題目要求的maxSupply
    constructor(
        string memory _name, 
        string memory _symbol, 
        uint256 _maxSupply)
        ERC721(_name, _symbol){
        //執行時填入10
        maxSupply = _maxSupply;
    }

    // 實作mint function，主要用來demo確認用
    function mint (uint256 amount) external avaialbeMint(amount){
        // 迴圈值星批量鑄造NFT
       for(uint256 i=0; i < amount ; i++){
            // 鑄造 NFT, counter為NFT的tokenId
            _mint(msg.sender, counter);
            counter ++ ;
       }
    }
    // 讓transfer無效
    function safeTransferFrom(address from, address to, uint256 tokenId, bytes memory data) public override  {
        revert();
    }
}

如何讓NFT圖片Opensea呈現

https://docs.opensea.io/docs/metadata-standards

• IPFS
  • https://www.pinata.cloud/
• Step1: 上傳圖片。
• Step2: 上傳符合Opensea標準的檔案

// SPDX-License-Identifier: GPL-3.0
pragma solidity >=0.8.20;

import "@openzeppelin/contracts/token/ERC721/ERC721.sol";


contract MyNFT is ERC721{

    using Strings for uint256;

    address owner;
    uint256 public maxSupply = 10; // 最大發行量
    bool private isOpened = false;//盲盒是否打開

    uint256 public counter = 0;

    modifier onlyOwner{
        require(msg.sender == owner);
        _;
    }

    constructor (string memory _name, string memory _symbol) ERC721(_name, _symbol){
        owner = msg.sender;
    }
    
    //開盲盒
    function openBlindBox() external onlyOwner{
        isOpened = true;
    }
    
    
    //設定NFT的baseURI(盲盒)
    function _baseURI() internal pure override returns (string memory) {
        return "ipfs://QmXxZBg4RnGxC2dDxfUSAmxgGooHsoncPQgCLiNw8kj3Ls/";
    }
    
    //查看NFT Metadata網址
    function tokenURI(uint256 tokenId) public view override returns (string memory) {
        if (!isOpened){
            return _baseURI();
        }
        return string(abi.encodePacked("ipfs://QmWQcaFFCm9ofyVN2ZwGbTGopLEbQ6QSc2Xn1C7ekKAYDF/", tokenId.toString(), ".json"));
        
    }

    // 實作mint function，主要用來demo確認用
    function mint (uint256 amount) external{
        require(amount + counter <= maxSupply, "over max supply.");
        // 迴圈批量鑄造NFT
        for(uint256 i=0; i < amount ; i++){
                // 鑄造 NFT, counter為NFT的tokenId
                _mint(msg.sender, counter);
                counter ++ ;
        }
    }

}

延伸：ERC721A合約！