---
# System prepended metadata

title: 第十一周周記

---

## 第十一周周記

#### 音樂播放器學習紀錄
```
#include "Arduino.h"
#include "SoftwareSerial.h"
#include "DFRobotDFPlayerMini.h"

SoftwareSerial mySoftwareSerial(11, 10); // RX, TX
DFRobotDFPlayerMini myDFPlayer;

void setup()
{
  mySoftwareSerial.begin(9600);
  Serial.begin(115200);
  
  Serial.println();
  Serial.println(F("DFRobot DFPlayer Mini Demo"));
  Serial.println(F("Initializing DFPlayer ... (May take 3~5 seconds)"));
  
  if (!myDFPlayer.begin(mySoftwareSerial)) {  //Use softwareSerial to communicate with mp3.
    Serial.println(F("Unable to begin:"));
    Serial.println(F("1.Please recheck the connection!"));
    Serial.println(F("2.Please insert the SD card!"));
    while(true){
      delay(0); // Code to compatible with ESP8266 watch dog.
    }
  }
  Serial.println(F("DFPlayer Mini online."));
  
  myDFPlayer.volume(30);  //Set volume value. From 0 to 30
  Serial.println(F("hi"));
  myDFPlayer.play(1);  //Play the first mp3
  delay(300);
  Serial.println(F("done"));
}

void loop()
{
  if (myDFPlayer.available()) {
    printDetail(myDFPlayer.readType(), myDFPlayer.read());
  }
}

void printDetail(uint8_t type, int value){
  switch (type) {
    case TimeOut:
      Serial.println(F("Time Out!"));
      break;
    case WrongStack:
      Serial.println(F("Stack Wrong!"));
      break;
    case DFPlayerCardInserted:
      Serial.println(F("Card Inserted!"));
      break;
    case DFPlayerCardRemoved:
      Serial.println(F("Card Removed!"));
      break;
    case DFPlayerCardOnline:
      Serial.println(F("Card Online!"));
      break;
    case DFPlayerUSBInserted:
      Serial.println("USB Inserted!");
      break;
    case DFPlayerUSBRemoved:
      Serial.println("USB Removed!");
      break;
    case DFPlayerPlayFinished:
      Serial.print(F("Number:"));
      Serial.print(value);
      Serial.println(F(" Play Finished!"));
      break;
    case DFPlayerError:
      Serial.print(F("DFPlayerError:"));
      switch (value) {
        case Busy:
          Serial.println(F("Card not found"));
          break;
        case Sleeping:
          Serial.println(F("Sleeping"));
          break;
        case SerialWrongStack:
          Serial.println(F("Get Wrong Stack"));
          break;
        case CheckSumNotMatch:
          Serial.println(F("Check Sum Not Match"));
          break;
        case FileIndexOut:
          Serial.println(F("File Index Out of Bound"));
          break;
        case FileMismatch:
          Serial.println(F("Cannot Find File"));
          break;
        case Advertise:
          Serial.println(F("In Advertise"));
          break;
        default:
          break;
      }
      break;
    default:
      break;
  }
}
```

### 專案設計相關
1. 裝置圖
![762E2F09-9E67-4A03-84F7-98CC7B9F6FCF](https://hackmd.io/_uploads/HJ7Io3v4a.jpg)
2. 相關技術
![58590714-2082-4528-B3B1-6CE8EFBF9BBE](https://hackmd.io/_uploads/rkXiinvNp.jpg)
- 使用馬達搭配捲線器控制階梯上下移動
- 在牆壁上刻出凹痕，讓階梯突起的那塊能夠穩定的上下移動
- 小人走路的部分目前只有想到用電磁鐵
3. 雷切 prototype
![S__10141913](https://hackmd.io/_uploads/S1e232vEa.jpg)
- 之後會考慮用 6mm 的板子，中間凹槽用 3mm 的板子，再用手動接合的
- 拿到一個新馬達，相較伺服馬達可以轉超過 180 度
- 卡榫的部分可以畫在兩邊的板子比較穩
