---
# System prepended metadata

title: Untitled

---

```
PREFIX : <https://www.example.org/gbm1/>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX obo: <http://purl.obolibrary.org/obo/>
PREFIX schema: <https://schema.org/>
PREFIX sio: <http://semanticscience.org/resource/>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>
PREFIX QUDT: <http://qudt.org/schema/qudt/>
PREFIX qudt: <http://qudt.org/schema/qudt/>

SOURCE gbm1_csv_file <GBM1.csv>

ITERATOR gbm1_csv <csvPerRow> {
    FIELD id <Identifier>
	FIELD gender <Gender>
	FIELD IDLabsite <ID Lab site>
	FIELD IDclinicalsite <ID clinical site>
	FIELD birthdate <DOB>
	FIELD Age <Age>
	FIELD dead <deceased (1=yes 0=no)>
	FIELD pathology <Pathology>
	FIELD localization <Localization>
	FIELD idh12status <IDH1/2 status>
	FIELD MGMTStatus <MGMT status>
	FIELD ECOG <ECOG>
	FIELD NatureOfInitialResection <Nature of initial resection>
	FIELD lymphocyteCountsAtV1 <lymphocyte counts at V1 in G/L>
	FIELD cummulativeDosePreV1SteroidSse <cummulative dose preV1 steroid use in mg>
	FIELD SteroidUseAfterV1 <steroid use after V1>
	FIELD CummulativeSteroidDose <cummulative steroid dose in mg>
	FIELD CyclesAdjTMZ <Cycles adj TMZ>
	FIELD DosesBevacizumab <doses bevacizumab>
	FIELD BestResponse <Best response>
	FIELD pseudoProgression <pseudo-progression (1=yes 0=no)>
	FIELD oedema <oedema>
	FIELD progression <progression (1=yes 0=no)>
	FIELD dateOfProgression <date of progression>
	FIELD monthsPFS <months PFS>
	FIELD monthsOS <months OS>
}

EXPRESSION gbmSubjects <gbm1_csv_file.gbm1_csv>

AUTOINCREMENT deadIDAuto <"deceased" + 0 + "id">
AUTOINCREMENT pathologyIDAuto <"pathology" + 0 + "id">
AUTOINCREMENT localizationIDAuto <"localization" + 0 +  "id">
AUTOINCREMENT idhIDAuto  <"idh" + 0 + "id">
AUTOINCREMENT mgmtIDAuto <"mgmtident" + 0 + "id">
AUTOINCREMENT ecogIDAuto <"ecog" + 0 + "id">


EXPRESSION deadID <gbmSubjects.id UNION gbmSubjects.dead UNION deadIDAuto>
EXPRESSION pathologyID <gbmSubjects.id UNION gbmSubjects.pathology UNION pathologyIDAuto>
EXPRESSION localizationID <gbmSubjects.id UNION gbmSubjects.localization UNION localizationIDAuto>
EXPRESSION idhID <gbmSubjects.id UNION gbmSubjects.idh12status UNION idhIDAuto>
EXPRESSION mgmtID <gbmSubjects.id UNION gbmSubjects.MGMTStatus UNION mgmtIDAuto>
EXPRESSION ecogID <gbmSubjects.id UNION gbmSubjects.ECOG UNION ecogIDAuto>

MATCHER genders <M as NCIT_C20197 & F as NCIT_C16576>
MATCHER dead <1 as true & 0 as false>
MATCHER pathology <GBM as DOID_3068 & AIII as NCIT_C129290>
MATCHER regions <"temporal L" as NCIT_C12353>
MATCHER IDH12Values <"wt" as NCIT_C136567 & "mut" as NCIT_C129264>
MATCHER MGMTValues <UnMeth as NCIT_C154335 & Meth as NCIT_C132902>
MATCHER ECOGValues <0 as NCIT_C105722 & 1 as NCIT_C105723 & 2 as NCIT_C105725 & 3 as NCIT_C105726 & 4 as NCIT_C105727>

:gbmPatient :[gbmSubjects.id] {
    rdf:type obo:NCIT_C16960 ;
    sio:SIO_000066 [gbmSubjects.IDLabsite] ;
    sio:SIO_000066 [gbmSubjects.IDclinicalsite] ;
    dct:identifier [gbmSubjects.id] ;
    sio:SIO_000223 @:subjectproperties ;
}

:subjectproperties _:[gbmSubjects.id] {
    schema:gender obo:[gbmSubjects.gender MATCHING genders] ;
    schema:birthdate [gbmSubjects.birthdate] ;
    foaf:age [gbmSubjects.Age] ;
    obo:RO_0000086 @:dead ;
    obo:RO_0000086 @:ecog ;
    schema:diagnosis @:pathology
}

:dead _:[deadID] {
    rdf:type obo:NCIT_C28554 ;
    rdf:value [gbmSubjects.dead MATCHING dead] ;
}

:ecog _:[ecogID] {
    rdf:type sio:SIO_000915 ;
    rdf:domain obo:NCIT_C102408 ;
    rdf:value obo:[gbmSubjects.ECOG MATCHING ECOGValues] ;
}

:pathology _:[pathologyID] {
    rdf:type obo:[gbmSubjects.pathology MATCHING pathology] ;
    wdt:P927 @:localization ;
    obo:NCIT_R108 @:idhstatus ;
    obo:NCIT_R108 @:mgmtstatus ;
}

:localization _:[localizationID] {
    rdf:type sio:SIO_000614 ;
    rdf:domain obo:NCIT_C13031
    rdfs:label [gbmSubjects.localization] ;
    rdf:value obo:[gbmSubjects.localization MATCHING regions] ;
}

:idhstatus _:[idhID] {
    rdf:type sio:SIO_000614 ;
    rdf:domain obo:NCIT_C129260 ;
    rdf:value obo:[gbmSubjects.idh12status MATCHING IDH12Values] ;
    obo:RO_0002507 obo:NCIT_C157185 ;
}

:mgmtstatus _:[mgmtID] {
    rdf:type obo:NCIT_C16631 ;
    rdf:domain obo:NCIT_C21232
    rdf:value obo:[gbmSubjects.MGMTStatus MATCHING MGMTValues] ;
    obo:RO_0002507 obo:NCIT_C158919 ;
}







```